Introduction to the Julia programming language

20 Symbolic Math¶

Symbolic math in Julia¶

Julia offers several packages for symbolic computer algebra, providing functionalities for symbolic manipulation, differentiation, integration, equation solving, and more. Here we focus on Symbolics.jl and SymPy.jl.

Symbolics.jl is a fast and modern Computer Algebra System (CAS) for a fast and modern programming language (Julia). The goal is to have a high-performance and parallelized symbolic algebra system that is directly extendable in the same language as that of the users.

SymPy.jl provides a Julia interface to the SymPy library in Python, which is a well-established symbolic mathematics library. It allows you to perform various symbolic operations including symbolic manipulation, solving equations, calculus, and more.

Derivatives¶

In [2]:
using Symbolics
In [3]:
@variables t
D = Differential(t)

z = t + t^2
D(z)
$$ \begin{equation} \frac{\mathrm{d}}{\mathrm{d}t} \left( t + t^{2} \right) \end{equation} $$

D is a lazy operator because it lets us symbolically represent "The derivative with respect to $t$". If we want to expand the derivative operators, we'd use expand_derivatives:

In [4]:
expand_derivatives(D(z))
$$ \begin{equation} 1 + 2 t \end{equation} $$

The variable, that you are taking the derivative with respect to, is accessed with:

In [5]:
D.x
$$ \begin{equation} t \end{equation} $$

Simplification and Substitution¶

In [6]:
@variables x y
simplify(2x + 2y)
$$ \begin{equation} 2 \left( x + y \right) \end{equation} $$
In [7]:
simplify(sin(x)^2+cos(x)^2)
$$ \begin{equation} 1 \end{equation} $$
In [8]:
simplify(cosh(x)^2-sinh(x)^2)
$$ \begin{equation} 1 \end{equation} $$

This can be applied to arrays by using Julia's broadcast mechanism:

In [9]:
B = simplify.([t + t^2 + t + t^2  2t + 4t
               x + y + y + 2t     x^2 - x^2 + y^2])
$$ \begin{equation} \left[ \begin{array}{cc} 2 \left( t + t^{2} \right) & 6 t \\ 2 \left( t + y \right) + x & y^{2} \\ \end{array} \right] \end{equation} $$

We can then use substitute to change values of an expression around:

In [10]:
simplify.(substitute.(B, (Dict(x => y^2),)))
$$ \begin{equation} \left[ \begin{array}{cc} 2 \left( t + t^{2} \right) & 6 t \\ 2 \left( t + y \right) + y^{2} & y^{2} \\ \end{array} \right] \end{equation} $$

Example: Error propagation with Symbolics.jl¶

In [11]:
function err_prop(f, vars)
    @variables sum
    sum = 0
    for (x, sigma) in vars
        D = Differential(x)
        sum += expand_derivatives(D(f))^2 * sigma^2 
    end
    return sqrt(simplify(sum))
end

err_prop (generic function with 1 method)

Take the volume of a cylinder as an example:

In [12]:
@variables r, h, σ_r, σ_h
V = pi * r^2 * h
σ_V = err_prop(V, [(r, σ_r), (h, σ_h)])
$$ \begin{equation} \sqrt{39.478 \sigma_{r}^{2} r^{2} h^{2} + 9.8696 \sigma_{h}^{2} r^{4}} \end{equation} $$

Plug in numerical values:

In [13]:
using Formatting

r_meas = 3 # cm
σ_r_meas = 0.1 # cm
h_meas = 5 # cm
σ_h_meas = 0.1; # cm

V_num = substitute(V, Dict(r => r_meas, h => h_meas))
σ_V_num = substitute(σ_V, (Dict(r => r_meas, σ_r => σ_r_meas, 
                     h => h_meas, σ_h => σ_h_meas)))

printfmt("V = ({:.2f} ± {:.2f}) cm^3", Symbolics.value(V_num), Symbolics.value(σ_V_num))

V = (141.37 ± 9.84) cm^3

Error propgation with Measurements.jl¶

For the particular problem of error propgation, there are also other tools, e.g., Measurements.jl

See arXiv:1610.08716

In [14]:
using Measurements

r = measurement(3, 0.1)
h = measurement(5, 0.1)
V = pi * r^2 * h
$141.4 \pm 9.8$

SymPy¶

In [15]:
using SymPy
@which simplify

WARNING: using SymPy.simplify in module Main conflicts with an existing identifier.
WARNING: using SymPy.Differential in module Main conflicts with an existing identifier.

SymbolicUtils
In [16]:
sympy.sqrt(2)
$\sqrt{2}$
In [17]:
sympy.sqrt(2).evalf(50)
$1.4142135623730950488016887242096980785696718753769$
In [18]:
x, y = sympy.symbols("x y")
x + 1/2
$x + 0.5$
In [19]:
x + sympy.S(1)/2
$x + \frac{1}{2}$

Expression manipulation¶

In [20]:
expr = sympy.cosh(x)^2 - sympy.sinh(x)^2
$- \sinh^{2}{\left(x \right)} + \cosh^{2}{\left(x \right)}$
In [21]:
sympy.simplify(expr)
$1$
In [22]:
sympy.trigsimp(2 * sin(x) * cos(x))
$\sin{\left(2 x \right)}$
In [23]:
sympy.factor(x^2 +2x +1)
$\left(x + 1\right)^{2}$

Differentiation¶

In [24]:
sympy.diff(sin(x)*exp(x), x)
$e^{x} \sin{\left(x \right)} + e^{x} \cos{\left(x \right)}$

Symbolic integration¶

In [25]:
sympy.integrate(exp(x)*sin(x) + exp(x)*cos(x), x)
$e^{x} \sin{\left(x \right)}$
In [26]:
sympy.integrate(cos(x)^2, (x, 0, pi))
$\frac{\pi}{2}$

Solving equations¶

In [27]:
sympy.solve(x^2 - 8x + 15, x)

2-element Vector{Sym{PyCall.PyObject}}:
 3
 5
In [36]:
eq1 = sympy.Eq(x + y, 5)
eq2 = sympy.Eq(x^2 + y^2, 17)
sympy.solve((eq1, eq2), (x, y))

2-element Vector{Tuple{Sym{PyCall.PyObject}, Sym{PyCall.PyObject}}}:
 (4, 1)
 (1, 4)

Substitution¶

In [29]:
expr = x^2 + y^2
expr.subs(x, 2)
$y^{2} + 4$
In [30]:
expr.subs([(x,3), (y,4)])
$25$

Variable transformation¶

In [33]:
using Latexify
x, y, z, r, phi, theta = sympy.symbols("x, y, z, r, theta, phi")
(x, y, z) = (r * sin(theta) * cos(phi), 
             r * sin(theta) * sin(phi), 
             r * cos(theta))
X = sympy.Matrix([x, y, z])
Y = sympy.Matrix([r, theta, phi])
J = X.jacobian(Y)
latexify(J)
\begin{equation} \left[ \begin{array}{ccc} \sin\left( \phi \right) \cdot \cos\left( \theta \right) & r \cdot \cos\left( \phi \right) \cdot \cos\left( \theta \right) & \left( - r \right) \cdot \sin\left( \phi \right) \cdot \sin\left( \theta \right) \\ \sin\left( \phi \right) \cdot \sin\left( \theta \right) & r \cdot \sin\left( \theta \right) \cdot \cos\left( \phi \right) & r \cdot \sin\left( \phi \right) \cdot \cos\left( \theta \right) \\ \cos\left( \phi \right) & \left( - r \right) \cdot \sin\left( \phi \right) & 0 \\ \end{array} \right] \end{equation}
In [32]:
sympy.simplify(J.det())
$r^{2} \sin{\left(\phi \right)}$